Fichier temporaires?

[ProGamer91]

Bonjour,

j'ai trouvé sur internent quelqu'un qui disait de rentrer la manipulation suivant dans cmd avec de supprimer sans prise de tête les fichiers temp.

del /F /S /Q c:\windows\temp\*

quelqu'un peut m'expliquer ce que cela fait vraiment une fois la commande entrée? A quoi correspond les "/F" "/S" "/Q"?

Et concernant ce qui se trouve dans "C:\Users\??????????\AppData\Local\Temp" on peut tout supprimer sans crainte?

Merci d'avance.

PS: Est-qu'il y a d'autres manip intéressant a effectuer afin de gagner de la place et en rapidité? Merci.

[RobinSG]

Bonjour,

Voici l'aide de la commande DEL :

Code: Tout sélectionner

C:\>del /?
Supprime un ou plusieurs fichiers.

DEL [/P] [/F] [/S] [/Q] [/A[[:]attributs]] noms
ERASE [/P] [/F] [/S] [/Q] [/A[[:]attributs]] noms

  noms          Spécifie une liste d'un ou plusieurs fichiers ou répertoires.
                Les caractères génériques peuvent être utilisés pour
                supprimer plusieurs fichiers. Si un répertoire est spécifié,
                tous les fichiers qu'il contient seront supprimés.

  /P            Demande une confirmation avant de supprimer un fichier.
  /F            Force la suppression de fichiers en lecture seule.
  /S            Supprime les fichiers dans tous les sous-répertoires.
  /Q            Pas de confirmation avant suppression avec car. génériques.
  /A            Suppression en fonction des attributs
  attributs     R  Fichiers en lecture seule     S  Fichiers système
                H  Fichiers cachés               A  Fichiers prêts pour archive
                I  Fichiers indexés sans contenu L  Points d'analyse
                -  Préfixe de négation

Si les extensions de commandes sont activées, DEL et ERASE sont modifiées
comme suit :
La logique d'affichage du commutateur /S est inversée. Elle
n'affiche que les fichiers supprimés, et pas ceux qui n'ont pas été trouvés.

Donc, ta commande supprime de manière forcée et silencieuse les fichiers et sous répertoires dans C:\Windows\Temp

Pour le temporaire de l'utilisateur, tu peux utiliser la variable d'environnement %temp%
En ligne de commande, tape :

Code: Tout sélectionner

cd %temp%

pour vérifier que la variable est bien définie.

Si c'est le vas, il suffit de remplacer le chemin C:\windows\temp par %temp%

Code: Tout sélectionner

del /f /s /q %temp%

[ProGamer91]

Merci pour ta réponse! Grâce à toi je comprends bien mieux ces commandes.

[ProGamer91]

Ah!! peux tu m'expliquer à quoi correspond le " \* " ?

Merci.

EDIT: j'ai trouvé cela sur un forum

Je cite: " Ou alors un petit script VBS a placer ds le dossier "démarrage" de Windows:
il détruit les "Temps" au lancement de win ;
par exemple, voici un bon VBS de M.Harris en Pjointe
(renommer le LOG en VBS,avant usage) "

Voici le script en question: Peux-t-on me dire si je peux l'utiliser sans risque et ce qu'il fait exactement? Merci.

Code: Tout sélectionner

'DeleteTempFiles.vbs - A utility to clean Win9x temp directory
'at boot.  Put a shortcut to this file in Startup directory.
'© Bill James - bill@billsway.com - rev 26 May 2002

'Original author - Michael Harris - posted to
'microsoft.public.scripting.vbs newsgroup on 28 Aug 1999.

'Modifications by Bill James: Added safety check for dangerous
'temp folder settting.  Revised summary popup to include
'savings for this run and cumulative savings to date.

'rev 26 May 2002 to add error trap for unformatted partition

Option Explicit

Dim fso,ws,Title
Set fso = CreateObject("Scripting.FileSystemObject")
Set ws = WScript.CreateObject("WScript.Shell")
Title = "Temp File Cleaner"

Dim TmpDir : TmpDir = ws.Environment("Process")("Temp")

ChkTmpSafe

Dim OldTmpSize : OldTmpSize = fso.GetFolder(TmpDir).size

Dim arFiles(),cnt,dcnt,Fldr,SubFldr,File
cnt = -1
dcnt = 0
DelTmpFiles TmpDir

DelEmptyFldrs TmpDir

Dim strF,strD,RptSize,TotSave
CalcSave

If dcnt >= 1 Then ws.Popup cnt & strF & dcnt & _
  strD & vbCRLF & vbCRLF & RptSize & vbCRLF & _
  vbCRLF & TotSave,60,Title

Cleanup

Sub ChkTmpSafe
Dim Drv,Unsafe,WinDir,ComDir,PgmDir,SysDir,UnsafeDir
  If TmpDir = "" Then
    ws.Popup "Unsafe condition detected.  %TEMP% " &_
    "Variable is not set.",60,Title,16
    Cleanup
    WScript.Quit
  End If
  If Not fso.FolderExists(TmpDir) Then
    fso.CreateFolder(TmpDir)
    Cleanup
    WScript.Quit
  End If
  For Each Drv In fso.Drives
    'If a drive or partition is not formatted, an error occurs
    On Error Resume Next
    If Drv.DriveType = 2 or Drv.DriveType = 3 Then _
      UnSafe = UnSafe & Drv.RootFolder & "|"
    On Error GoTo 0
  Next
  Unsafe = Unsafe & fso.GetSpecialFolder(0) & "|"
  Unsafe = Unsafe & fso.GetSpecialFolder(0) & "\Command|"
  Unsafe = Unsafe & ws.RegRead("HKLM\Software\Microsoft" _
    & "\Windows\CurrentVersion\ProgramFilesPath") & "|"
  Unsafe = Unsafe & fso.getspecialfolder(1)
  Unsafe = Split(Unsafe,"|",-1,1)
  For Each UnsafeDir In Unsafe
    If UCase(UnsafeDir) = UCase(TmpDir) Or _
    UCase(UnsafeDir) & "\" = UCase(TmpDir) Or _
    UCase(UnsafeDir) = UCase(TmpDir) & "\" Then
      ws.Popup "Unsafe condition detected.  %TEMP% " &_
      "Variable is set to " & TmpDir,60,Title,16
      Cleanup
      WScript.Quit
    End If
  Next
End Sub

Sub DelTmpFiles(FldrSpec)
  Set Fldr = fso.GetFolder(FldrSpec)
  For Each File In Fldr.Files
    cnt = cnt + 1
    Redim Preserve arFiles(cnt)
    Set arFiles(cnt) = File
  Next
  For Each SubFldr in Fldr.SubFolders
    DelTmpFiles SubFldr
  Next
  For Each file in arFiles
    On Error Resume Next
    file.Delete True
    If Err.Number = 0 Then dcnt = dcnt + 1
    Err.Clear
  Next
End Sub

Sub DelEmptyFldrs(FldrSpec)
  Set Fldr = fso.GetFolder(FldrSpec)
  For Each SubFldr in Fldr.SubFolders
    DelEmptyFldrs SubFldr
  Next
  On Error Resume Next
  If UCase(Fldr.Path) <> UCase(TmpDir) Then
    If Fldr.Files.Count = 0 Then
      If Fldr.SubFolders.Count = 0 Then
        Fldr.Delete
      End If
    End If
  End If
  If Err.Number = 76 Then
    Err.Clear
    On Error GoTo 0
    DelEmptyFldrs(TmpDir)
  End If
End Sub

Sub CalcSave
  Dim NewTmpSize,SaveSize,s1,s2
  Dim TmpClnLog,OldSave,HideLog,Log
  NewTmpSize = fso.GetFolder(TmpDir).size
  SaveSize = OldTmpSize - NewTmpSize
  s1 = " free space reclaimed."
  If SaveSize < 1024 Then
    RptSize = SaveSize & " bytes" & s1
  ElseIf SaveSize < 1048576 Then
    RptSize = Round(SaveSize / 1024) & " KB" & s1
  Else RptSize = Round(SaveSize / 1048576) & " MB" & s1
  End If
  Log = fso.GetSpecialFolder(0) & "\TempClean.Log"
  If Not fso.FileExists(Log) Then fso.CreateTextFile(Log)
  If fso.GetFile(Log).Size = 0 Then
    Set TmpClnLog = fso.OpenTextFile(Log,8,True)
    TmpClnLog.WriteBlankLines(1)
  End If
  Set TmpClnLog = fso.OpenTextFile(Log,1)
  OldSave = TmpClnLog.ReadLine
  If Not IsNumeric(OldSave) Then OldSave = 0
  TotSave = OldSave + SaveSize
  Set TmpClnLog = fso.OpenTextFile(Log,2)
  TmpClnLog.WriteLine TotSave
  TmpClnLog.Close
  s2 = " reclaimed to date."
  If TotSave < 1024 Then
    TotSave = TotSave & " bytes" & s2
  ElseIf TotSave < 1048576 Then
    TotSave = Round(TotSave / 1024) & " KB" & s2
  Else TotSave = Round(TotSave / 1048576) & " MB" & s2
  End If
  cnt = cnt + 1
  If cnt = 1 Then strF = " file found, " _
    Else strF = " files found, "
  If dcnt = 1 Then strD = " file deleted." _
    Else strD = " files deleted."
  Set TmpClnLog = Nothing
End Sub

Sub Cleanup
  Set fso = Nothing
  Set ws = Nothing
  Set Fldr = Nothing
End Sub

[ProGamer91]

:up: merci

[RobinSG]

Ce script vérifie que la variable %TEMP% existe et est définie sur un répertoire accessible.
Ensuite, il supprime les fichiers dans ce répertoire et ses sous répertoires.
Puis il supprime les sous-répertoires si ils sont vides.
Enfin, il affiche un résumé de la taille gagnée.

PS : Le ' * ' est un caractère générique.

[ProGamer91]

Merci pour ta réponse, cela éclaire ma lanterne.

Je vais donc utiliser ce script sans crainte.